GridView自定义分页的四种存储过程

首先要说说为什么不用GridView的默认的分页功能，GridView控件并非真正知道如何获得一个新页面，它只是请求绑定的数据源控件返回适合规定页面的行，分页最终是由数据源控件完成。

1. 为什么不使用GridView的默认分页功能

首先要说说为什么不用GridView的默认的分页功能，GridView控件并非真正知道如何获得一个新页面，它只是请求绑定的数据源控件返回适合规定页面的行，分页最终是由数据源控件完成。当我们使用SqlDataSource或使用以上的代码处理分页时。每次这个页面被请求或者回发时，所有和这个SELECT语句匹配的记录都被读取并存储到一个内部的DataSet中，但只显示适合当前页面大小的记录数。也就是说有可能使用Select语句返回1000000条记录，而每次回发只显示10条记录。如果启用了SqlDataSource上的缓存，通过把EnableCaching设置为true，则情况会更好一些。在这种情况下，我们只须访问一次数据库服务器，整个数据集只加载一次，并在指定的期限内存储在ASP.NET缓存中。只要数据保持缓存状态，显示任何页面将无须再次访问数据库服务器。然而，可能有大量数据存储在内存中，换而言之，Web服务器的压力大大的增加了。因此，如果要使用SqlDataSource来获取较小的数据时，GridView内建的自动分页可能足够高效了，但对于大数据量来说是不合适的。

2. 分页的四种存储过程(分页+排序的版本请参考Blog里其他文章)

在大多数情况下我们使用存储过程来进行分页，今天有空总结了一下使用存储过程对GridView进行分页的4种写法(分别是使用Top关键字，临时表，临时表变量和SQL Server 2005 新加的Row_Number()函数)

后续的文章中还将涉及GridView控件使用ObjectDataSource自定义分页 + 排序，Repeater控件自定义分页 + 排序，有兴趣的朋友可以参考。
代码如下:
if exists(select 1 from sys.objects where name = 'GetProductsCount' and type = 'P')
drop proc GetProductsCount
go
CREATE PROCEDURE GetProductsCount
as
select count(*) from products
go

--1.使用Top
if exists(select 1 from sys.objects where name = 'GetProductsByPage' and type = 'P')
drop proc GetProductsByPage
go
CREATE PROCEDURE GetProductsByPage
@PageNumber int,
@PageSize int
AS
declare @sql nvarchar(4000)
set @sql = 'select top ' + Convert(varchar, @PageSize)
+ ' * from products where productid not in (select top ' + Convert(varchar, (@PageNumber - 1) * @PageSize) + ' productid from products)'
exec sp_executesql @sql
go

--exec GetProductsByPage 1, 10
--exec GetProductsByPage 5, 10

--2.使用临时表
if exists(select 1 from sys.objects where name = 'GetProductsByPage' and type = 'P')
drop proc GetProductsByPage
go
CREATE PROCEDURE GetProductsByPage
@PageNumber int,
@PageSize int
AS
-- 创建临时表
CREATE TABLE #TempProducts
(
ID int IDENTITY PRIMARY KEY,
ProductID int,
ProductName varchar(40) ,
SupplierID int,
CategoryID int,
QuantityPerUnit nvarchar(20),
UnitPrice money,
UnitsInStock smallint,
UnitsOnOrder smallint,
ReorderLevel smallint,
Discontinued bit
)
-- 填充临时表
INSERT INTO #TempProducts
(ProductID, ProductName, SupplierID, CategoryID, QuantityPerUnit, UnitPrice, UnitsInStock, UnitsOnOrder, ReorderLevel, Discontinued)
SELECT ProductID, ProductName, SupplierID, CategoryID, QuantityPerUnit, UnitPrice, UnitsInStock, UnitsOnOrder, ReorderLevel, Discontinued
FROM Products

DECLARE @FromID int
DECLARE @ToID int
SET @FromID = ((@PageNumber - 1) * @PageSize) + 1
SET @ToID = @PageNumber * @PageSize

SELECT ProductID, ProductName, SupplierID, CategoryID, QuantityPerUnit, UnitPrice, UnitsInStock, UnitsOnOrder, ReorderLevel, Discontinued
FROM #TempProducts
WHERE ID >= @FromID AND ID <= @ToID
go

--exec GetProductsByPage 1, 10
--exec GetProductsByPage 5, 10

--3.使用表变量
/*
为要分页的数据创建一个table变量,这个table变量里有一个作为主健的IDENTITY列.这样需要分页的每条记录在table变量里就和一个row index(通过IDENTITY列)关联起来了.一旦table变量产生,连接数据库表的SELECT语句就被执行,获取需要的记录.SET ROWCOUNT用来限制放到table变量里的记录的数量.
当SET ROWCOUNT的值指定为PageNumber * PageSize时,这个方法的效率取决于被请求的页数.对于比较前面的页来说– 比如开始几页的数据– 这种方法非常有效. 但是对接近尾部的页来说,这种方法的效率和默认分页时差不多
*/
if exists(select 1 from sys.objects where name = 'GetProductsByPage' and type = 'P')
drop proc GetProductsByPage
go
CREATE PROCEDURE GetProductsByPage
@PageNumber int,
@PageSize int
AS
DECLARE @TempProducts TABLE
(
ID int IDENTITY,
productid int
)
DECLARE @maxRows int
SET @maxRows = @PageNumber * @PageSize
--在返回指定的行数之后停止处理查询
SET ROWCOUNT @maxRows

INSERT INTO @TempProducts (productid)
SELECT productid
FROM products
ORDER BY productid

SET ROWCOUNT @PageSize

SELECT p.*
FROM @TempProducts t INNER JOIN products p
ON t.productid = p.productid
WHERE ID > (@PageNumber - 1) * @PageSize
SET ROWCOUNT 0
GO

--exec GetProductsByPage 1, 10
--exec GetProductsByPage 5, 10

--4.使用row_number函数
--SQL Server 2005的新特性,它可以将记录根据一定的顺序排列,每条记录和一个等级相关 这个等级可以用来作为每条记录的row index.
if exists(select 1 from sys.objects where name = 'GetProductsByPage' and type = 'P')
drop proc GetProductsByPage
go
CREATE PROCEDURE GetProductsByPage
@PageNumber int,
@PageSize int
AS
select ProductID, ProductName, SupplierID, CategoryID, QuantityPerUnit, UnitPrice, UnitsInStock, UnitsOnOrder, ReorderLevel, Discontinued
from
(select row_number() Over (order by productid) as row,ProductID, ProductName, SupplierID, CategoryID, QuantityPerUnit, UnitPrice, UnitsInStock, UnitsOnOrder, ReorderLevel, Discontinued
from products) as ProductsWithRowNumber
where row between (@PageNumber - 1) * @PageSize + 1 and @PageNumber * @PageSize
go

--exec GetProductsByPage 1, 10
--exec GetProductsByPage 5, 10

3. 在GridView中的应用

代码如下:
<%@ Page Language="C#" AutoEventWireup="true" CodeFile="GridViewPaging.aspx.cs" Inherits="GridViewPaging" %>

4.分页效果图: