Oracle存储过程和自定义函数详解

概述

PL/SQL中的过程和函数（通常称为子程序）是PL/SQL块的一种特殊的类型，这种类型的子程序可以以编译的形式存放在数据库中，并为后续的程序块调用。

相同点： 完成特定功能的程序

不同点：是否用return语句返回值。

举个例子：

create or replace procedure PrintStudents(p_staffName in xgj_test.username%type) as

 cursor c_testData is
 select t.sal, t.comm from xgj_test t where t.username = p_staffName;

begin

 for v_info in c_testData loop
 DBMS_OUTPUT.PUT_LINE(v_info.sal || ' ' || v_info.comm);
 end loop;

end PrintStudents;

</div>

一旦创建了改程序并将其存储在数据库中，就可以使用如下的方式调用该过程

begin
 PrintStudents('Computer Science');
 PrintStudents('Match');
end;
/

</div>

或者

exec PrintStudents('Computer Science');
exec PrintStudents('Match');

</div>

在命令窗口中：

在pl/sql工具的sql窗口中：

存储过程的创建和调用

基本语法

create [ or replace] procedure procedure_name
[( argument [ {IN | OUT | IN OUT }] type,
......
argument [ {IN | OUT | IN OUT }] type ) ] { IS | AS}
procedure_body

</div>

无参的存储过程

/**
 无参数的存过
 打印hello world

 调用存储过程：
 1. exec sayhelloworld();
 2 begin 
 sayhelloworld();
 end;
 /

*/
create or replace procedure sayhelloworld
as
--说明部分
begin
 dbms_output.put_line('hello world');
end sayhelloworld;

</div>

调用过程：

SQL> set serveroutput on ;
SQL> exec sayhelloworld();

hello world

PL/SQL procedure successfully completed

SQL> begin
 2 sayhelloworld();
 3 sayhelloworld();
 4 end;
 5 /

hello world
hello world

PL/SQL procedure successfully completed

</div>

带参数的存储过程

/**
创建一个带参数的存储过程

给指定的员工增加工资，并打印增长前后的工资

*/
create or replace procedure addSalary(staffName in xgj_test.username%type )
as
--定义一个变量保存调整之前的薪水
oldSalary xgj_test.sal%type;

begin
 --查询员工涨之前的薪水
 select t.sal into oldSalary from xgj_test t where t.username=staffName; 

 --调整薪水
 update xgj_test t set t.sal = sal+1000 where t.username=staffName ;

 --输出
 dbms_output.put_line('调整之前的薪水:'|| oldSalary || ' ,调整之后的薪水:' || (oldSalary + 1000));

end addSalary;

</div>

可以看到，update语句之后并没有commit的操作。

一般来讲为了保证事务的一致性，由调用者来提交比较合适，当然了是需要区分具体的业务需求的~

begin 
addSalary('xiao');
addSalary('gong');
commit ;
end ;
/

</div>

存储函数

基本语法

create [ or replace] function function_name
[( argument [ {IN | OUT | IN OUT }] type,
......
argument [ {IN | OUT | IN OUT }] type ) ] 
RETURN { IS | AS}
function_body

</div>

其中 return子句是必须存在的，一个函数如果没有执行return就结束将发生错误，这一点和存过有说不同。

存储函数

准备的数据如下：

/**
查询员工的年薪 （月工资*12 + 奖金）
*/

create or replace function querySalaryInCome(staffName in varchar2)

 return number as
 --定义变量保存员工的工资和奖金
 pSalary xgj_test.sal%type;
 pComm xgj_test.comm%type;

begin
 --查询员工的工资和奖金
 select t.sal, t.comm
 into pSalary, pComm
 from xgj_test t
 where t.username = staffName;
 --直接返回年薪
 return pSalary * 12 + pComm;
end querySalaryInCome;

</div>

存在一个问题，当奖金为空的时候，算出来的年收入竟然是空的。

因为 如果一个表达式中有空值，那么这个表达式的结果即为空值。

所以我们需要对空值进行处理， 使用nvl函数即可。

最后修改后的function为

create or replace function querySalaryInCome(staffName in varchar2)

 return number as
 --定义变量保存员工的工资和奖金
 pSalary xgj_test.sal%type;
 pComm xgj_test.comm%type;

begin
 --查询员工的工资和奖金
 select t.sal, t.comm
 into pSalary, pComm
 from xgj_test t
 where t.username = staffName;
 --直接返回年薪
 return pSalary * 12 + nvl(pComm,0);
end querySalaryInCome;

</div>

out参数

一般来讲，存储过程和存储函数的区别在于存储函数可以有一个返回值，而存储过程没有返回值。

• 存储过程和存储函数都可以有out参数
• 存储过程和存储函数都可以有多个out参数
• 存储过程可以通过out参数实现返回值
  

那我们如何选择存储过程和存储函数呢？

原则：

如果只有一个返回值，用存储函数，否则（即没有返回值或者有多个返回值）使用存储过程。

/**
根据员工姓名，查询员工的全部信息
*/
create or replace procedure QueryStaffInfo(staffName in xgj_test.username%type,
           pSal out number,
           pComm out xgj_test.comm%type,
           pJob out xgj_test.job%type) 

is

begin
 --查询该员工的薪资，奖金和职位
 select t.sal,t.comm,t.job into pSal,pComm,pJob from xgj_test t where t.username=staffName;
end QueryStaffInfo;

</div>

先抛出两个思考问题：

• 查询员工的所有信息–> out参数太多怎么办？
• 查询某个部门中所有员工的信息–> out中返回集合？

后面会讲到如何解决？ 总不能一个个的写out吧~

在应用中访问存储过程和存储函数

概述

我们使用Java程序连接Oracle数据库。

使用jar: ojdbc14.jar

关于oracle官方提供的几个jar的区别

• classes12.jar (1,600,090 bytes) - for use with JDK 1.2 and JDK 1.3
• classes12_g.jar (2,044,594 bytes) - same as classes12.jar, except that classes were compiled with “javac -g” and contain some tracing information.
• classes12dms.jar (1,607,745 bytes) - same as classes12.jar, except that it contains additional code`to support Oracle Dynamic Monitoring Service.
• classes12dms_g.jar (2,052,968 bytes) - same as classes12dms.jar except that classes were compiled with “javac -g” and contain some tracing information.
• ojdbc14.jar (1,545,954 bytes) - classes for use with JDK 1.4 and 1.5
• ojdbc14_g.jar (1,938,906 bytes) - same as ojdbc14.jar, except that classes were compiled with “javac -g” and contain some tracing information.
• ojdbc14dms.jar (1,553,561 bytes) - same as ojdbc14.jar, except that it contains additional code`to support Oracle Dynamic Monitoring Service.
• ojdbc14dms_g.jar (1,947,136 bytes) - same as ojdbc14dms.jar, except that classes were compiled with “javac -g” an