在DOS下有这样的命令type 文件名，使用这个命令可查看文件的内容，要处理的文件名直接跟在程序名后，这种用法很普遍，在Windows下仍然如此，只是可能你没感觉到罢啦。双击一个文本文件，系统就用记事本打开这文件，实际上就是将你所双击的文件名作为记事本的参数来处理的。
所以作为windows下的这类程序，可先从命令行获取要处理的文件名，若命令行上取不到，再显示“打开文件”对话框让用户选择一个文件也不晚！
下面的例子将从命令行提取要处理的文件名，假设文件名是位于程序名后的第一个参数。
----------------------------------------------------------
;文件名：15.asm
;取命令行参数并显示，用于分析命令行参数可能出现的情况
.386
.model flat,stdcall
Option CaseMap:none
include windows.inc
include kernel32.inc
include user32.inc
include masm32.inc
includelib kernel32.lib
includelib user32.lib
includelib masm32.lib
.data
szCaption db "GetCommandLine",0
.data?
FileName db 256 dup(?)
.code
GetFileNameFromCommandLine PROTO :LPSTR ;用来存放处理后的文件名
start:
invoke GetFileNameFromCommandLine,addr FileName
.if eax!=NULL
invoke MessageBox,NULL,eax,addr szCaption,MB_OK
.endif
invoke ExitProcess,NULL
;返回时若eax=NULL则表示无法从命令行提取被处理的文件
;否则eax指向文件名地址
GetFileNameFromCommandLine proc uses esi edi ,lpString:LPSTR
mov edi,lpString
invoke GetCommandLine ;取命令行参数
mov esi,eax
xor eax,eax
cld
;跳过程序名项，该项可能处在双引号中间
G1:
lodsb
cmp al,'"' ;程序名以双引号开始吗？
jnz G3
G2:
lodsb
cmp al,'"' ;引号表示程序名项的结束
jnz G2
G3:
lodsb ;程序名项和后面的参数间至少有一空白
cmp al,' '
jnz G3
;跳过空白和制表，指向文件名
G4:
lodsb
cmp al,0
jz G7
cmp al,' '
jz G4
cmp al,9
jz G4
cmp al,'"' ;文件名也是以双引号开始吗？
jnz G5
stosb
G4p:
lodsb
stosb
cmp al,'"' ;找到引号就是文件名的结束
jnz G4p
jmp G6
;跳到文件的末尾
G5:
stosb ;将文件名传输到缓冲区
lodsb
cmp al,0
jz G6
cmp al,' '
jz G6
cmp al,9
jnz G5
G6:
xor al,al ;缓冲区中文件名结束
stosb
mov eax,lpString ;eax指向缓冲区首地址
G7:
ret
GetFileNameFromCommandLine endp
end start
-----------------------------------------------------------------
执行示例：
D:\KZ_Z>GetFileName "\My documents\pop.exe"
D:\KZ_Z>GetFileName Cala.exe